Извините, ничего не найдено.

Не расстраивайся! Лучше выпей чайку!
Регистрация
Справка
Календарь

Вернуться   forum.boolean.name > Программирование игр для компьютеров > Blitz3D > Переводы

Переводы Переводы туториалов и хелпов.

Ответ
 
Опции темы
Старый 03.09.2005, 19:07   #1
alcosholik
 
Сообщений: n/a
Хорошо

Полный перевод раздела Command Reference -> 2D-Category -> File/Stream из стандартного хелпа Blitz.
 
Ответить с цитированием
Старый 03.09.2005, 19:08   #2
alcosholik
 
Сообщений: n/a
Eof (указатель_на_файл/поток)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше)

Описание
Проверяет, был ли достигнут конец открытого файла или потока. Используйте, чтобы определить нужно продолжать считывание информации из файла/потока или нет. Команду необходимо использовать, чтобы прочитать текстовый файл неизвестной длины (например, ReadMe.txt) и вывести его содержимое на экран. См. пример.

Eof возвращает 1, если был достигнут конец файла или, в случае с TCP потоком, если он (поток) был благополучно закрыт.

Eof возвращает –1, если что-либо пошло не так во время обработки потока.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Eof – пример использования 

file$="c:autoexec.bat" 

filein = ReadFile(file$) 

Print "Вот ваш файл Autoexec.bat ..." 

; Повторять, пока не будет достигнут конец файла 
While Not Eof(filein) 
Print ReadLine$(filein) 
Wend
 
Ответить с цитированием
Старый 03.09.2005, 19:09   #3
alcosholik
 
Сообщений: n/a
ReadAvail (указатель_на_файл/указатель_на_поток)

Параметры
указатель_на_файл/указатель_на_поток = переменная, назначенная файлу или потоку при его открытии

Описание
В случае с файловыми потоками, эта команда показывает, какое количество данных хранится внутри. В случае с TCP потоками, команда показывает, какое количество данных «прибыло».

Пример
; OpenTCPStream/CloseTCPStream/ReadAvail – пример использования

Print "Подключаемся..." 
tcp=OpenTCPStream( "www.blitzbasement.com",80 ) 

If Not tcp Print "Неудача.":WaitKey:End 

Print "Подключились! Посылаем запрос..." 

WriteLine tcp,"GET http://www.blitzbasement.com HTTP/1.0" 
WriteLine tcp,Chr$(10) 

If Eof(tcp) Print "Неудача.":WaitKey:End 

Print "Запрос послан! Ожидание ответа..." 

While Not Eof(tcp) 
Print ReadLine$( tcp ) 
Print "Доступно байт:" + ReadAvail(tcp) 
Wend 

If Eof(tcp)=1 Then Print "Успех!" Else Print "Ошибка!" 

CloseTCPStream tcp 

WaitKey
 
Ответить с цитированием
Старый 03.09.2005, 19:09   #4
alcosholik
 
Сообщений: n/a
ReadByte (указатель_на_файл/поток)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше)

Описание
Как только вы открыли файл на диске (или поток) для чтения, используйте эту команду для считывания одного байта из файла/потока за раз. Заметьте, что байт – это целое число, которое может приминать значения в диапазоне от 0 до 255 и использует 8 бит для хранения. Поскольку символы сохраняются как байтовые значения, эта функция может быть использована для считывания из файла одного символа за раз.

Дополнительные замечания
Значение, сохраненное командой WriteByte, является «младшим» байтом integer-числа. Т.е. отрицательные числа и числа больше, чем 255 все равно будут иметь значения в пределах 0 и 255. Это может показаться вам странным, если вы не совсем понимаете принцип хранения 32-битных integer-чисел, но это НЕ глюк.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись в файл, используя функции ReadByte и WriteByte

; Инициализировать несколько переменных для примера 
Byte1% = 10; хранить 10 
Byte2% = 100; хранить 100 
Byte3% = 255; хранить 255 (максимальное значение, которое может хранить байт) 
Byte4% = 256; попробуйте сохранить 256, вы получите 0 (256 – 256 = 0)
Byte5% = 257; попробуйте сохранить 257, вы получите 1 (257 - 256 = 1) 
Byte6% = -1; попробуйте сохранить –1, вы получите 255 (256 – 1 = 255)
Byte7% = -2; попробуйте сохранить 256, вы получите 254 (256 – 2 = 254)
Byte8% = Asc("A"); хранить ASCII код символа “A” (65 )
;(английская и русская «А» имеют разные коды – прим. перев.) 

; Открыть файл для записи 
fileout = WriteFile("mydata.dat ") 

; Записать информацию в файл 
WriteByte( fileout, Byte1 ) 
WriteByte( fileout, Byte2 ) 
WriteByte( fileout, Byte3 ) 
WriteByte( fileout, Byte4 ) 
WriteByte( fileout, Byte5 ) 
WriteByte( fileout, Byte6 ) 
WriteByte( fileout, Byte7 ) 
WriteByte( fileout, Byte8 ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1 = ReadByte( filein ) 
Read2 = ReadByte( filein ) 
Read3 = ReadByte( filein ) 
Read4 = ReadByte( filein ) 
Read5 = ReadByte( filein ) 
Read6 = ReadByte( filein ) 
Read7 = ReadByte( filein ) 
Read8 = ReadByte( filein ) 

; Закрыть файл после завершения чтения 
CloseFile( filein ) 

Print "Записано - считано" 
Write Byte1 + " - " : Print Read1 
Write Byte2 + " - " : Print Read2 
Write Byte3 + " - " : Print Read3 
Write Byte4 + " - " : Print Read4 
Write Byte5 + " - " : Print Read5 
Write Byte6 + " - " : Print Read6 
Write Byte7 + " - " : Print Read7 
Write Byte8 + " - " : Print Chr$( Read8 ) 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:10   #5
alcosholik
 
Сообщений: n/a
ReadShort (указатель_на_файл)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше)
Возвращаемое значение – integer-число в диапазоне 0-65535

Описание
Как только вы открыли файл на диске (или поток) для чтения, используйте эту команду для считывания одного short integer (16 бит) значения из файла. Заметьте, что каждое записанное значение использует 2 байта дискового пространства, и первым будет записан «младший» байт. Чтение за пределами конца файла не вызовет ошибку, но каждое считанное значение будет равно 0.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись файла, используя функции ReadShort и WriteShort

; Инициализировать несколько переменных для примера
Int1% = 10; хранить 10 
Int2% = 365; хранить 365
Int3% = 32767; 32767, максимальное положительное значение типа Short Integer в Blitz Basic )
Int4% = -32768; -32768, максимальное отрицательное значение типа Short Integer в Blitz Basic )

; Открыть файл для записи
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл
WriteShort( fileout, Int1 ) 
WriteShort( fileout, Int2 ) 
WriteShort( fileout, Int3 ) 
WriteShort( fileout, Int4 ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1 = ReadShort( filein ) 
Read2 = ReadShort( filein ) 
Read3 = ReadShort( filein ) 
Read4 = ReadShort( filein ) 

; Закрыть файл после завершения чтения 
CloseFile( filein ) 

Print "Данные типа Short Integer, считанные из файла mydata.dat " 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:11   #6
alcosholik
 
Сообщений: n/a
ReadInt (указатель_на_файл/поток)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше)
Возвращаемое значение – integer-число в диапазоне от –2147483648 до 2147483648

Описание
Как только вы открыли файл на диске (или поток) для чтения, используйте эту команду для считывания одного integer значения из файла. Заметьте, что каждое записанное значение использует 4 байта дискового пространства, и первым будет записан «младший» байт. Чтение за пределами конца файла не вызовет ошибку, но каждое считанное значение будет равно 0.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись в файл, используя функции ReadInt и WriteInt

; Инициализировать несколько переменных для примера 
Int1% = 10; хранить 10
Int2% = 365; хранить 365
Int3% = 2147483647; хранить 2147483647, максимальное положительное значение типа Integer в Blitz Basic )
Int4% = - 2147483648; хранить –2147483648, максимальное отрицательное значение типа Integer в Blitz Basic )
 
; Открыть файл для записи 
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл
WriteInt( fileout, Int1 ) 
WriteInt( fileout, Int2 ) 
WriteInt( fileout, Int3 ) 
WriteInt( fileout, Int4 ) 

; Закрыть файл
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1 = ReadInt( filein ) 
Read2 = ReadInt( filein ) 
Read3 = ReadInt( filein ) 
Read4 = ReadInt( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Данные типа Integer, считанные из файла mydata.dat " 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:12   #7
alcosholik
 
Сообщений: n/a
ReadFloat (указатель_на_файл/поток)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше)
Возвращаемое значение – дробное число

Описание
Как только вы открыли файл на диске (или поток) для чтения, используйте эту команду для считывания одного дробного числа из файла. Заметьте, что каждое записанное значение использует 4 байта дискового пространства. Чтение за пределами конца файла не вызовет ошибку, но каждое считанное значение будет равно 0.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись файла, используя функции ReadFloat и WriteFloat

; Инициализировать несколько переменных для примера
Num1# = 10.5; хранить 10.5 
Num2# = 365.25; хранить 365.25 
Num3# = 32767.123; 32767.123, максимальное положительное значение типа Floating Point в Blitz Basic )
Num4# = -32768.123; -32768.123, максимальное отрицательное значение типа Floating Point в Blitz Basic)
 
; Открыть файл для записи 
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл
WriteFloat( fileout, Num1 ) 
WriteFloat( fileout, Num2 ) 
WriteFloat( fileout, Num3 ) 
WriteFloat( fileout, Num4 ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения
filein = ReadFile("mydata.dat") 

Read1# = ReadFloat( filein ) 
Read2# = ReadFloat( filein ) 
Read3# = ReadFloat( filein ) 
Read4# = ReadFloat( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Данные типа Floating Point, считанные из файла mydata.dat " 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:13   #8
alcosholik
 
Сообщений: n/a
ReadString$ (указатель_на_файл/поток)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше). Возвращаемое значение – текстовая строка.

Описание
Как только вы открыли файл на диске (или поток) для чтения, используйте эту команду для считывания строковой переменной из файла.

Каждая хранящаяся в файле строка представляет собой 4-байтовое (32-битное) integer-число, за которым следуют символы, формирующие строку. Integer-число содержит информацию о количестве символов в строке, т.е. ее длину. Заметьте, что символы «возврат каретки», «перевод строки» и Null НЕ используются для обозначения конца строки. Файл из строк не может быть прочитан, как текстовый файл, так как он содержит строковые переменные, а не текст. Нулевая строка, т.е. строка нулевой длины (“”) занимает 4 байта, integer-число со значением 0, за которым не следуют никакие символы. Строки не ограничены 255 символами, как в некоторых языках программирования. Чтение за пределами конца файла не вызовет ошибку, но каждое считанное значение будет строкой нулевой длины.

Эта команда должна быть использована только при чтении из двоичного файла или потока. С текстовыми файлами необходимо использовать ReadLine.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

См. также: WriteString, OpenTCPStream, ReadFile, ReadLine, ReadByte, ReadShort, ReadInt, ReadFloat, ReadBytes, ReadAvail.

Пример
; Чтение и запись в файл, используя функции ReadString$ и WriteString

; Инициализировать несколько переменных для примера
String1$ = "Короткая строка" 
String2$ = "Более длинная строка" 
String3$ = "Это строка 3," 
String4$ = "соединенная со строкой 4"

; Открыть файл для записи
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл 
WriteString( fileout, String1 ) 
WriteString( fileout, String2 ) 
WriteString( fileout, String3 + String4) 
WriteString( fileout, " Как видно, не обязательно использовать переменные." ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1$ = ReadString$( filein ) 
Read2$ = ReadString$( filein ) 
Read3$ = ReadString$( filein ) 
Read4$ = ReadString$( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Строковые переменные, считанные из файла mydata.dat " 
Print 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:14   #9
alcosholik
 
Сообщений: n/a
ReadLine$ (указатель_на_файл/поток)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше). Функция возвращает строковое значение

Описание
Как только вы открыли файл на диске (или поток) для чтения, используйте эту команду для считывания целой строки текста из текстового файла или потока. Каждая строка текста возвращается как строковая переменная. Эта функция может быть использована для чтения простых текстовых файлов.

Символы считываются из файла до тех пор, пока не будет достигнута метка «конец файла». «Концом строки» может быть или только символ «возврата каретки» (0Dh), или только «перевод строки» (0Ah), или «возврат каретки», за которым следует «перевод строки» (0Dh, 0Ah). К каждой строке текста автоматически добавляется метка «конец файла», состоящая из символа «возврата каретки», за которым следует символ «перевода строки» (т.е. 0Dh, 0Ah). Чтение за пределами конца файла не вызовет ошибку, но каждое считанное значение будет строкой нулевой длины.

ReadLine$ возвращает все символы, за исключением chr$(13)/chr$(10) («возврат каретки» и «перевод строки» - прим. перев.)

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись в файл, используя функции ReadLine$ и WriteLine$
 
; Инициализировать несколько переменных для примера
String1$ = "Строка 1 короткая" 
String2$ = "Строка 2 более длинная строка, они могут быть еще длинней " 
String3$ = "Строка 3 составлена " 
String4$ = "из двух частей, соединенных вместе." 

; Открыть файл для записи 
fileout = WriteFile("mydata.txt") 

; Записать информацию в файл
WriteLine( fileout, String1 ) 
WriteLine( fileout, String2 ) 
WriteLine( fileout, String3 + String4) 
WriteLine( fileout, "Как видно, не обязательно использовать переменные." ) 

; Закрыть файл
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.txt") 

Read1$ = ReadLine( filein ) 
Read2$ = ReadLine$( filein ) 
Read3$ = ReadLine$( filein ) 
Read4$ = ReadLine$( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Текстовые строки, считанные из файла mydata.txt " 
Print 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:15   #10
alcosholik
 
Сообщений: n/a
ReadBytes банк_памяти, файл/поток, смещение, счетчик

Параметры
банк_памяти = переменная, которая содержит указатель на банк памяти
файл/поток = указатель на ранее открытый файл или поток
смещение = смещение в байтах для записи значения
счетчик = сколько байт записать от смещения

Описание
Вы можете прочесть содержимое файла на диске (или потока) и сохранить его в банке памяти, используя эту команду.

Примечание: указатель на файл должен быть определен командой OpenFile или OpenTCPStream и в последствии закрыт командой CloseFile или CloseTCPStream после всех операций считывания.

Команда возвращает количество байт, успешно считанных из потока.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

См. также: WriteBytes.

Пример
; Read/WriteBytes – пример использования

; Создать банк памяти объемом 50 байт
bnkTest=CreateBank(500) 

; Заполнить банк памяти случайными данными 
For t = 1 To 50 

PokeByte bnkTest,t,Rnd(255) 

Next 

; Открыть файл для записи 
fileBank=WriteFile("test.bnk") 
; Записать содержимое банка памяти в файл 
WriteBytes bnkTest,fileBank,0,50 
; Закрыть файл
CloseFile fileBank 

; Очистить банк памяти
FreeBank bnkTest 

; Создать новый
bnkTest=CreateBank(500) 

; Открыть файл для чтения 
fileBank=OpenFile("test.bnk") 
; Считать из файла в банк памяти 
ReadBytes bnkTest,fileBank,0,50 
; Закрыть файл 
CloseFile fileBank 

; Вывести на экран результат 
For t = 1 To 50 

Print PeekByte (bnkTest,t) 

Next
 
Ответить с цитированием
Старый 03.09.2005, 19:16   #11
alcosholik
 
Сообщений: n/a
WriteByte (указатель_на_файл/поток, мой_байт)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше)
мой_байт = может быть целым или дробным числом, но правильно сохранены будут только значения от 0 до 255

Описание
Как только вы открыли файл на диске (или поток) для записи, используйте эту команду, чтобы записать один байт в файл/поток за раз. Заметьте, что байт – это целое число, которое может приминать значения в диапазоне от 0 до 255 и использует 8 бит для хранения. Поскольку символы сохраняются как байтовые значения, эта функция может быть использована для записи в файл одного символа за раз.

Дополнительные замечания
Значение, сохраненное командой WriteByte, является «младшим» байтом integer-числа. Т.е. отрицательные числа и числа больше, чем 255 все равно будут иметь значения в пределах 0 и 255. Это может показаться вам странным, если вы не совсем понимаете принцип хранения 32-битных integer-чисел, но это НЕ глюк.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись в файл, используя функции ReadByte и WriteByte

; Инициализировать несколько переменных для примера 
Byte1% = 10; хранить 10 
Byte2% = 100; хранить 100 
Byte3% = 255; хранить 255 (максимальное значение, которое может хранить байт) 
Byte4% = 256; попробуйте сохранить 256, вы получите 0 (256 – 256 = 0)
Byte5% = 257; попробуйте сохранить 257, вы получите 1 (257 - 256 = 1) 
Byte6% = -1; попробуйте сохранить –1, вы получите 255 (256 – 1 = 255)
Byte7% = -2; попробуйте сохранить 256, вы получите 254 (256 – 2 = 254)
Byte8% = Asc("A"); хранить ASCII код символа “A” (65 )
;(английская и русская «А» имеют разные коды – прим. перев.) 

; Открыть файл для записи 
fileout = WriteFile("mydata.dat ") 

; Записать информацию в файл 
WriteByte( fileout, Byte1 ) 
WriteByte( fileout, Byte2 ) 
WriteByte( fileout, Byte3 ) 
WriteByte( fileout, Byte4 ) 
WriteByte( fileout, Byte5 ) 
WriteByte( fileout, Byte6 ) 
WriteByte( fileout, Byte7 ) 
WriteByte( fileout, Byte8 ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1 = ReadByte( filein ) 
Read2 = ReadByte( filein ) 
Read3 = ReadByte( filein ) 
Read4 = ReadByte( filein ) 
Read5 = ReadByte( filein ) 
Read6 = ReadByte( filein ) 
Read7 = ReadByte( filein ) 
Read8 = ReadByte( filein ) 

; Закрыть файл после завершения чтения 
CloseFile( filein ) 

Print "Записано - считано" 
Write Byte1 + " - " : Print Read1 
Write Byte2 + " - " : Print Read2 
Write Byte3 + " - " : Print Read3 
Write Byte4 + " - " : Print Read4 
Write Byte5 + " - " : Print Read5 
Write Byte6 + " - " : Print Read6 
Write Byte7 + " - " : Print Read7 
Write Byte8 + " - " : Print Chr$( Read8 ) 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:17   #12
alcosholik
 
Сообщений: n/a
WriteShort (указатель_на_файл/поток, integer_число)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, WriteFile или OpenTCPStream (версия 1.52 и выше)
integer_число = целое число (может быть использовано дробное число, но оно будет преобразовано в тип integer перед сохранением, сохранится только его целочисленная часть)

Описание
Как только вы открыли файл на диске (или поток) для записи, используйте эту команду, чтобы записать одно short integer (16 бит) значение в файл. Заметьте, что каждое записанное значение использует 2 байта дискового пространства, и первым будет записан «младший» байт. Диапазон записываемых значений – от 0 до 65535.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись файла, используя функции ReadShort и WriteShort

; Инициализировать несколько переменных для примера
Int1% = 10; хранить 10 
Int2% = 365; хранить 365
Int3% = 32767; 32767, максимальное положительное значение типа Short Integer в Blitz Basic )
Int4% = -32768; -32768, максимальное отрицательное значение типа Short Integer в Blitz Basic )

; Открыть файл для записи
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл
WriteShort( fileout, Int1 ) 
WriteShort( fileout, Int2 ) 
WriteShort( fileout, Int3 ) 
WriteShort( fileout, Int4 ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1 = ReadShort( filein ) 
Read2 = ReadShort( filein ) 
Read3 = ReadShort( filein ) 
Read4 = ReadShort( filein ) 

; Закрыть файл после завершения чтения 
CloseFile( filein ) 

Print "Данные типа Short Integer, считанные из файла mydata.dat " 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:18   #13
alcosholik
 
Сообщений: n/a
WriteInt (указатель_на_файл/поток, integer_число)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, WriteFile или OpenTCPStream (версия 1.52 и выше)
integer_число = целое число (может быть использовано дробное число, но оно будет преобразовано в тип integer перед сохранением, сохранится только его целочисленная часть)

Описание
Как только вы открыли файл на диске (или поток) для записи, используйте эту команду, чтобы записать одно integer значение в файл. Заметьте, что каждое записанное значение использует 4 байта дискового пространства, и первым будет записан «младший» байт. Диапазон записываемых значений – от -2147483648 до 2147483648.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись в файл, используя функции ReadInt и WriteInt

; Инициализировать несколько переменных для примера 
Int1% = 10; хранить 10
Int2% = 365; хранить 365
Int3% = 2147483647; хранить 2147483647, максимальное положительное значение типа Integer в Blitz Basic )
Int4% = - 2147483648; хранить –2147483648, максимальное отрицательное значение типа Integer в Blitz Basic )
 
; Открыть файл для записи 
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл
WriteInt( fileout, Int1 ) 
WriteInt( fileout, Int2 ) 
WriteInt( fileout, Int3 ) 
WriteInt( fileout, Int4 ) 

; Закрыть файл
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1 = ReadInt( filein ) 
Read2 = ReadInt( filein ) 
Read3 = ReadInt( filein ) 
Read4 = ReadInt( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Данные типа Integer, считанные из файла mydata.dat " 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:18   #14
alcosholik
 
Сообщений: n/a
WriteFloat (указатель_на_файл/поток, float_число)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, WriteFile или OpenTCPStream (версия 1.52 и выше)
float_число = дробное число

Описание
Как только вы открыли файл на диске (или поток) для записи, используйте эту команду, чтобы записать одно дробное число в файл. Заметьте, что каждое записанное значение использует 4 байта дискового пространства

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись файла, используя функции ReadFloat и WriteFloat

; Инициализировать несколько переменных для примера
Num1# = 10.5; хранить 10.5 
Num2# = 365.25; хранить 365.25 
Num3# = 32767.123; 32767.123, максимальное положительное значение типа Floating Point в Blitz Basic )
Num4# = -32768.123; -32768.123, максимальное отрицательное значение типа Floating Point в Blitz Basic)
 
; Открыть файл для записи 
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл
WriteFloat( fileout, Num1 ) 
WriteFloat( fileout, Num2 ) 
WriteFloat( fileout, Num3 ) 
WriteFloat( fileout, Num4 ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения
filein = ReadFile("mydata.dat") 

Read1# = ReadFloat( filein ) 
Read2# = ReadFloat( filein ) 
Read3# = ReadFloat( filein ) 
Read4# = ReadFloat( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Данные типа Floating Point, считанные из файла mydata.dat " 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Старый 03.09.2005, 19:19   #15
alcosholik
 
Сообщений: n/a
WriteString$ (указатель_на_файл/поток, моя_строка$)

Параметры
указатель_на_файл/поток = переменная, определенная командой OpenFile, ReadFile или OpenTCPStream (версия 1.52 и выше). Возвращаемое значение – текстовая строка.
моя_строка$ = любая строковая переменная или текст, заключенный в кавычки

Описание
Как только вы открыли файл на диске (или поток) для записи, используйте эту команду, чтобы записать строковую переменную в файл.

Каждая хранящаяся в файле строка представляет собой 4-байтовое (32-битное) integer-число, за которым следуют символы, формирующие строку. Integer-число содержит информацию о количестве символов в строке, т.е. ее длину. Заметьте, что символы «возврат каретки», «перевод строки» и Null НЕ используются для обозначения конца строки. Файл из строк не может быть прочитан, как текстовый файл, так как он содержит строковые переменные, а не текст. Нулевая строка, т.е. строка нулевой длины (“”) занимает 4 байта, integer-число со значением 0, за которым не следуют никакие символы. Строки не ограничены 255 символами, как в некоторых языках программирования. Чтение за пределами конца файла не вызовет ошибку, но каждое считанное значение будет строкой нулевой длины.

Потоками можно пользоваться только в версии Blitz Basic 1.52 или выше.

Пример
; Чтение и запись в файл, используя функции ReadString$ и WriteString

; Инициализировать несколько переменных для примера
String1$ = "Короткая строка" 
String2$ = "Более длинная строка" 
String3$ = "Это строка 3," 
String4$ = "соединенная со строкой 4"

; Открыть файл для записи
fileout = WriteFile("mydata.dat") 

; Записать информацию в файл 
WriteString( fileout, String1 ) 
WriteString( fileout, String2 ) 
WriteString( fileout, String3 + String4) 
WriteString( fileout, " Как видно, не обязательно использовать переменные." ) 

; Закрыть файл 
CloseFile( fileout ) 

; Открыть файл для чтения 
filein = ReadFile("mydata.dat") 

Read1$ = ReadString$( filein ) 
Read2$ = ReadString$( filein ) 
Read3$ = ReadString$( filein ) 
Read4$ = ReadString$( filein ) 

; Закрыть файл после завершения чтения
CloseFile( filein ) 

Print "Строковые переменные, считанные из файла mydata.dat " 
Print 
Print Read1 
Print Read2 
Print Read3 
Print Read4 

WaitKey()
 
Ответить с цитированием
Ответ


Опции темы

Ваши права в разделе
Вы не можете создавать темы
Вы не можете отвечать на сообщения
Вы не можете прикреплять файлы
Вы не можете редактировать сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.

Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Перевод хелпа - Type impersonalis Переводы 16 19.03.2010 09:16
Перевод хелпа - String alcosholik Переводы 0 15.01.2006 23:03
Перевод хелпа - Text alcosholik Переводы 12 15.10.2005 22:22
Перевод хелпа - Bank alcosholik Переводы 13 03.09.2005 21:51
Перевод хелпа - File alcosholik Переводы 17 03.09.2005 19:05


Часовой пояс GMT +4, время: 18:19.


vBulletin® Version 3.6.5.
Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Перевод: zCarot
Style crйe par Allan - vBulletin-Ressources.com