
Целью работы является изучение взаимодействия микроконтроллера 80C31 с внешними устройствами через параллельные порты, освоение практических методов обслуживания и программирования клавиатур в микропроцессорных системах и реализация на их основе командных декодеров.
Разработать программы для решения следующих задач:

Задача 1
Программа, которая анализирует номер нажатой клавиши и формирует соответствующий символ на семисегментном индикаторе. 

Задача 2
Программа, осуществляющая считывание четырех последовательно вводимых с клавиатуры чисел и их вывод на четыре семисегментных индикатора. 

Задача 3
Программа опроса клавиатуры, имеющая защиту от одновременного нажатия двух и более клавиш.

Задачи №1 и 3
Исходный код программы

KeyCod equ 20h;ячейка, в которой хранится код нажатой клавиши
NumKey equ 21h;ячейка, в которой хранится код символа нажатой клавиши
ljmp Start;прыжок в начало программы 
org 30h;начальный адрес программы
Start:;метка начала программы
;сброс 2ух старших разрядов световых индикаторов        DD1

     mov DPTR,#8000h;
     clr a;
     movx @DPTR,a;

     ; сброс 2ух младших разрядов световых индикаторов        DD4

     mov DPTR,#0A000h;
     clr a;
     movx @DPTR,a;

     ;сброс светового индикатора                  DD10

     mov DPTR,#0B000h;
     mov a,#0ffh;
     movx @DPTR,a;
mov tmod,#01h;инициализация T/C0: режим «1»
MainCycle:;метка главного цикла
acall ReadKey;вызов п/п опроса клавиатуры
jnc MainCycle;клавиша нажата? (CY==0)
acall DocKey;вызов п/п определения кода нажатой клавиши
;---

mov DPTR,#0A000h;выбор контекста вывода – два 

;младших разряда 7-сегментных индикаторов

mov a,NumKey;помещаем в аккумулятор код символа нажатой клавиши
movx @DPTR,a;выводим значение аккумулятора на индикатор
;---

ajmp MainCycle;возврат к опросу клавиатуры
;п/п опроса клавиатуры
ReadKey:

mov p1,#0ffh

clr C;очищаем флаг переноса – признак нажатия клавиши
clr P1.0;проверяем ряд клавиш А1-А4
mov a,p1

cjne a,#0feh,Hit;ДА?! – переходим к устранению дребезга контактов
setb p1.0;нет – восстанавливаем состояние ряда.
clr p1.1;проверяем ряд клавиш В1-В4
mov a,p1

cjne a,#0fdh,Hit;ДА?! – переходим к устранению дребезга контактов
setb p1.1;нет – восстанавливаем состояние ряда.
clr p1.2;проверяем ряд клавиш С1-С4
mov a,p1

cjne a,#0fbh,Hit;ДА?! – переходим к устранению дребезга контактов
sjmp zzz;ни одна из клавиш не была нажата – выход из п\п («прыжок» в конец)
Hit:;повторный ввод кода нажатой клавиши для устранения дребезга контактов
clr C

mov B,a;backup кода
mov th0,#0F8h;формирование задержки длительностью
mov tl0,#0f0h;10 мс с помощью T/C0
acall Delay;выдерживаем паузу
mov a,p1;повторное считывание нажатой клавиши
mov p1,#0ffh;восстанавливаем состояния линий
cjne a,b,zzz;коды не совпали!!! Выходим из п\п («прыжок» в конец)
mov KeyCod,a;коды совпали! Клавиша действительно нажата!


;заносим код клавиши в ячейку KeyCod
setb c;поднимаем флаг признака нажатия клавиши
zzz:

ret;возврат
DocKey:;п/п кодирования символа клавиши
mov a,KeyCod;помещаем код клавиши в аккумулятор для анализа
;подробнее о процедуре анализа см. в пояснении
    jb 0E0h, A1

       jnb 0E3h, A2

       jnb 0E4h, A3

       jnb 0E5h, A4

       mov a,#10h

       ajmp A0

       A2:

       mov a,#1d

       ajmp A0

       A3:

       mov a,#4d

       ajmp A0

       A4:

       mov a,#7d

       ajmp A0

    A1:

    jb 0E1h, A5

       jnb 0E3h, A6

       jnb 0E4h, A7

       jnb 0E5h, A8

       mov a,#0d

       ajmp A0

       A6:

       mov a,#2d

       ajmp A0

       A7:

       mov a,#5d

       ajmp A0

       A8:

       mov a,#8d

       ajmp A0

    A5:

       jnb 0E3h, A9

       jnb 0E4h, A10

       jnb 0E5h, A11

       mov a,#11h

       ajmp A0

       A9:

       mov a,#3d

       ajmp A0

       A10:

       mov a,#6d

       ajmp A0

       A11:

       mov a,#9d

    A0:

swap a

mov NumKey,a;сохраняем код клавиши согласно оговоренной кодировке
ret;возврат

Delay:;подпрограмма формирования временной задержки
      setb TR0;запуск T/C0
      jnb TF0,$;ожидание переполнения
      clr TR0;выключение T/C0
      clr TF0;сброс флага переполнения
ret;возврат

end;конец
Пояснения к программе.

В данной программной реализации объединены решения задач 1 и 3 настоящей лабораторной работы.
Основной интерес представляет подпрограмма, ставящая коду клавиши в соответствие код символа, обозначающего данную клавишу в принятой кодировке.

	Клавиша
	Код клавиши
P1.7 … P1.0
	Код символа согласно кодировке

	0
	10111101
	0

	1
	11110110
	1

	2
	11110101
	2

	3
	11110011
	3

	4
	11101110
	4

	5
	11101101
	5

	6
	11101011
	6

	7
	11011110
	7

	8
	11011101
	8

	9
	11011011
	9

	#
	10111011
	11h

	*
	10111110
	10h

Ниже приведена блок схема алгоритма.

Рассмотрим алгоритм генерации кода в действии.
На фотографии оператор нажимает клавишу «7» на клавиатуре.

Пройдём по дереву переходов блок-схемы.

На начало выполнения подпрограммы в аккумуляторе хранится число «110111102».
Три младших бита (110) кодируют номер столбца, в котором находится нажатая клавиша (по низкому уровню – 1ый столбец), следующие 4 бита (1011) кодируют номер строки, в котором находится нажатая клавиша (по низкому уровню – 3яя строка).
Запишем последовательность работы подпрограммы:

ACC.0==1? Нет → ACC.3==0? Нет → ACC.4==0? Нет → ACC.5==0? Да → GoTo A4 → AC=7d → GoTo A0 → swap AC → конец.
Таким образом, после завершения анализа в аккумулятор будет загружено число «7», после чего будет произведён взаимный обмен тетрадами, для адекватного отображения числа на индикаторе («07», а не «70»).
Подпрограмма опроса клавиатуры «проглотит» множественное нажатие кнопок, если они находятся в одном столбце (если в разных – будут выбраны нажатые кнопки из столбца с наименьшим порядковым номером). Например, зажаты кнопки «1», «4», «7» и «*» - код «нажатой клавиши» равен «100001102». Однако, подпрограмма кодировки, за счёт своей структуры, воспримет только одну нажатую клавишу (код которой будет воспринят раньше других, в данном случае – это «1»).
ACC.0==1? Нет → ACC.3==0? Да → GoTo A2 → АС=1d→ GoTo A0 → swap AC → конец.
Задача №2
Исходный код программы

Num1 equ 22h;здесь мы будем хранить число A B
Num2 equ 23h;а здесь – C D (на индикаторы будет ABCD)
Counter equ 24h; состояние ввода
KeyCod equ 20h;ячейка, в которой хранится код нажатой клавиши
NumKey equ 21h;ячейка, в которой хранится код символа нажатой клавиши
;установка стартовых значений

mov Num1,#0h

mov Num2,#0h

mov Counter,#0h

ljmp Start;прыжок в начало программы 
org 30h;начальный адрес программы
Start:;метка начала программы
;сброс 2ух старших разрядов световых индикаторов        DD1

     mov DPTR,#8000h;
     clr a;
     movx @DPTR,a;

     ; сброс 2ух младших разрядов световых индикаторов        DD4

     mov DPTR,#0A000h;
     clr a;
     movx @DPTR,a;

     ;сброс светового индикатора                  DD10

     mov DPTR,#0B000h;
     mov a,#0ffh;
     movx @DPTR,a;

mov tmod,#01h;инициализация T/C0: режим «1»
MainCycle:;метка главного цикла
acall ReadKey;вызов п/п опроса клавиатуры
jnc MainCycle;клавиша нажата? (CY==0)
acall DocKey;вызов п/п определения кода нажатой клавиши
;---

mov DPTR,#08000h;выбор контекста вывода – два 

;старших разряда 7-сегментных индикаторов
mov a,Num1; AB
movx @DPTR,a

mov DPTR,#0A000h;выбор контекста вывода – два 

;младших разряда 7-сегментных индикаторов
mov a,Num2; СD
movx @DPTR,a

;---

ajmp MainCycle;возврат к опросу клавиатуры

;п/п опроса клавиатуры

ReadKey:

mov p1,#0ffh

clr C;очищаем флаг переноса – признак нажатия клавиши
clr P1.0;проверяем ряд клавиш А1-А4
mov a,p1

cjne a,#0feh,Hit;ДА?! – переходим к устранению дребезга контактов
setb p1.0;нет – восстанавливаем состояние ряда.

clr p1.1;проверяем ряд клавиш В1-В4
mov a,p1

cjne a,#0fdh,Hit;ДА?! – переходим к устранению дребезга контактов
setb p1.1;нет – восстанавливаем состояние ряда.
clr p1.2;проверяем ряд клавиш С1-С4
mov a,p1

cjne a,#0fbh,Hit;ДА?! – переходим к устранению дребезга контактов
sjmp zzz;ни одна из клавиш не была нажата – выход из п\п («прыжок» в конец)
Hit:;повторный ввод кода нажатой клавиши для устранения дребезга контактов

clr C

mov B,a;backup кода
mov th0,#0F8h;формирование задержки длительностью
mov tl0,#0f0h;10 мс с помощью T/C0
acall Delay;выдерживаем паузу
mov a,p1;повторное считывание нажатой клавиши
mov p1,#0ffh;восстанавливаем состояния линий
cjne a,b,zzz;коды не совпали!!! Выходим из п\п («прыжок» в конец)
mov KeyCod,a;коды совпали! Клавиша действительно нажата!



;заносим код клавиши в ячейку KeyCod
setb c;поднимаем флаг признака нажатия клавиши
zzz:

ret;возврат

DocKey:;п/п кодирования символа клавиши
mov a,KeyCod;помещаем код клавиши в аккумулятор для анализа
;п\п в целом аналогична оной в предыдущей задаче (см.) кроме 2ух «моментов» :
    jb 0E0h, A1

       jnb 0E3h, A2

       jnb 0E4h, A3

       jnb 0E5h, A4

       ljmp zzz;заглушка для кодирования клавиши «*» (ей нет места среди цифр!)
       A2:

       mov a,#1h

       ljmp A0

       A3:

       mov a,#4h

       ljmp A0

       A4:

       mov a,#7h

       ljmp A0

    A1:

    jb 0E1h, A5

       jnb 0E3h, A6

       jnb 0E4h, A7

       jnb 0E5h, A8

       mov a,#0h

       ajmp A0

       A6:

       mov a,#2h

       ljmp A0

       A7:

       mov a,#5h

       ljmp A0

       A8:

       mov a,#8h

       ljmp A0

    A5:

       jnb 0E3h, A9

       jnb 0E4h, A10

       jnb 0E5h, A11

       ljmp zzz;заглушка для кодирования клавиши «#» (ей нет места среди цифр!)
       A9:

       mov a,#3h

       ljmp A0

       A10:

       mov a,#6h

       ljmp A0

       A11:

       mov a,#9h

    A0:

mov NumKey,a;сохраняем кодировку клавиши
;приступаем к обработке состояния ввода
mov a,Counter

inc Counter;устанавливаем следующее состояние для следующего прохода
cjne a,#0h,T1

ljmp S1;переход на состояние «0»
T1:

cjne a,#1h,T2

ljmp S2; переход на состояние «1»
T2:

cjne a,#2h,T3

ljmp S3; переход на состояние «2»
T3:

cjne a,#3h,T4

ljmp S4; переход на состояние «3»
T4:

ljmp Delay1; переход на состояние «ввод запрещён!»
;0000 (на индикаторах слева направо)
 S1:; заносим первую цифру A «A000»
    mov Num1,NumKey

    ret

 S2:

    mov a,Num1;выгружаем первую цифру в аккумулятор
    swap a;меняем тетрады местами 

; «A000» → «0A00» (на индикаторах слева направо)
    add a,NumKey;добавляем вторую цифру. Теперь в аккумуляторе BA

; «0A00» → «BA00» (на индикаторах слева направо)
    swap a;меняем тетрады местами 

; «BA00» → «AB00» (на индикаторах слева направо)
    mov Num1,a;выгружаем полученное число
    ret

 S3: ; заносим третью цифру C
    mov Num2,NumKey; «ABС0» (на индикаторах слева направо)
    ret

 S4:
    mov a,Num2

    swap a; «AB0С» (на индикаторах слева направо)
    add a,NumKey; «ABDС» (на индикаторах слева направо)
    swap a; «ABСD» (на индикаторах слева направо)
    mov Num2,a

    ret

ret;возврат
Delay:;подпрограмма формирования временной задержки
      setb TR0;запуск T/C0
      jnb TF0,$;ожидание переполнения
      clr TR0;выключение T/C0
      clr TF0;сброс флага переполнения
ret;возврат

Delay1:;HLT!
nop;пустой оператор
end;конец
Пояснения к программе.

В данной программной реализации была модифицирована ранее написанная подпрограмма кодировки – в ней были поставлены заглушки на обработку не цифровых клавиш («*» и «#»). Код, ранее помещающий кодировки этих клавиш в аккумулятор, теперь заменён  безусловным переход « ljmp zzz  ». На самом деле, этот переход можно сразу заменить командой возврата (т.к. именно на неё и ссылается метка «zzz»), но приведённое здесь решение является более интересным с точки зрения обфускации (от лат. obfuscare ) кода и иллюстрации принципа работы стека возвратов.
Кроме того, в подпрограмму кодировки добавлен код, управляющий записью кода текущей клавиши в одну из 4х тетрад (2 байта, представленные переменными Num1 и Num2) на основе текущего значения управляющей переменной Counter.
	Counter (значения)
	Обработка нажатия

	0
	Ввод 1ой цифры

	1
	Ввод 2ой цифры

	2
	Ввод 3ей цифры

	3
	Ввод 4ой цифры

	4
	Переход в режим «ввод запрещён»


Управление вводом, таким образом, реализовано через конечный автомат - абстракцию, позволяющую описывать пути изменения состояния объекта в зависимости от его текущего состояния и входных данных, при условии, что общее возможное количество состояний конечно (автоматная парадигма программирования).

На фотографии, оператор уже нажал последовательно клавиши «4», «8» и «5», о чём можно судить по показаниям индикаторов (как и описано здесь – цифры отобразились слева направо) и положению руки оператора.
Примечание: авторы отчёта намеренно, оставили имя переменной KeyCod (ключевая треска) в своих программах без изменений, чтобы выдержать стилистику базового примера.

