На весь экран - пропорции

[xmarat]

Если сделать так:

Graphics 1024, 768, 32 


То вся картинка растягивается на весь экран, и, если монитор 1366x768, все получается сплющенным. Я бы хотел сделать так, чтоб если монитор широкоформатный, то по краям появлялись черные полоски, если наоборот, то полоски сверху, или вообще не появляются если пропорции монитора соответствуют 1024x768(например 1280×1024), в общем как у плееров реализовано. Кто нибудь знает как это сделать? Заранее благодарен...

[Tadeus]

http://forum.boolean.name/showthread.php?p=174690 ?

[xmarat]

Да. Вопрос аналогичный. Однако вопрос остался открытым.

[ffinder]

Сообщение от xmarat

Я бы хотел сделать так, чтоб если монитор широкоформатный, то по краям появлялись черные полоски, если наоборот, то полоски сверху, или вообще не появляются если пропорции монитора соответствуют 1024x768(например 1280×1024)

CameraViewport camera,x,y,width,height

Параметры

camera - указатель камеры
x - координата x верхнего левого угла окна ( области просмотра)
y - координата y верхнего левого угла окна
width - ширина окна
height - высота окна Описание

Устанавливает позицию области просмотра камеры и ее размер.
Область просмотра камеры - 2D-область экрана, в которой отображаются рассматриваемые камерой объекты.
Установки области просмотра камеры позволяют Вам получать эффекты нескольких окон с разным видом и зеркал.



найдено тут: help.boolean.name в разделе 3d

[Randomize]

раздел BlitzMax!
юзать надо просто SetViewport
Формулу расчёта бери из данной ранее ссылки.

[xmarat]

А как узнать какое разрешение у монитора?

[Randomize]

Extern "Win32"
    Function GetSystemMetrics:Int(Axis:Int)
EndExtern
Local DesktopWidth:Int = GetSystemMetrics(0)
Local DesktopHeight:Int = GetSystemMetrics(1)

Graphics(DesktopWidth,DesktopHeight) 


[xmarat]

Эмм... А нет другого способа определить, а то я на Linux'е. Blitzmax не захотел это компилировать...

[ffinder]

на линухе кури мануал про xlib

[Randomize]

Сообщение от ffinder

на линухе кури мануал про xlib

Опередил

Сообщение от xmarat

Эмм... А нет другого способа определить, а то я на Linux'е. Blitzmax не захотел это компилировать...

SuperStrict
Import "-lXrandr"
Import "screen.cpp"

Extern
    Function GetScreenSize:Int(width:Int Var,height:Int Var) 
EndExtern

Local desktopWidth:Int
Local desktopHeight:Int

Local error:Int = GetScreenSize(width, height) 


И собственно сишный сорс:
screen.cpp

#include<stdio.h>
#include<stdlib.h>
#include<string.h>
#include<unistd.h>
#include<X11/Xlib.h>
#include<X11/extensions/Xrandr.h>

extern "C" int GetScreenSize(int&,int&);  // Makes the function visable to other files

int GetScreenSize(int& width, int& height)
{

         int num_sizes;
         Rotation original_rotation;

         Display *dpy = XOpenDisplay(NULL);
         Window root = RootWindow(dpy, 0);
         XRRScreenSize *xrrs = XRRSizes(dpy, 0, &num_sizes);
         //
         //     GET CURRENT RESOLUTION AND FREQUENCY
         //
         XRRScreenConfiguration *conf = XRRGetScreenInfo(dpy, root);
         short original_rate = XRRConfigCurrentRate(conf);
         SizeID original_size_id = XRRConfigCurrentConfiguration(conf, &original_rotation);

          width = xrrs[original_size_id].width;
          height = xrrs[original_size_id].height;
 
         XCloseDisplay(dpy);
        return 0; 
    } 


[xmarat]

Спасибо огромное Randomize!!! Это то что нужно. Вопрос на будущее: при компиляции в windows, с этим(код ниже) будет аналогично?

Extern "Win32" 
    Function GetSystemMetrics:Int(Axis:Int) 
EndExtern 
Local DesktopWidth:Int = GetSystemMetrics(0) 
Local DesktopHeight:Int = GetSystemMetrics(1) 

Graphics(DesktopWidth,DesktopHeight) 


[Randomize]

Есть директивы:

?Win32
 Код для Windows
?MacOs
 Код для макоси
?Linux
  Код для линукса
? 


[xmarat]

Не знал что так можно. Полезная вещь, буду знать. А как можно узнать размер дисплея в MacOS?

[SBJoker]

Для макос должен пример для линукса подойти.

[Randomize]

Сообщение от xmarat

Не знал что так можно. Полезная вещь, буду знать. А как можно узнать размер дисплея в MacOS?

?Win32
    Import pub.win32
    Private
    Extern
        Function ReleaseDC(hwnd:Int, hdc:Int)"Win32" 
    End Extern
    Public
?MacOS
    Import "macscreen.c"
    Private
    Extern
        Function CGDisplayCurrentMode:Byte Ptr(displayID:Byte Ptr)"MacOS"
        Function CGGetActiveDisplayList:Byte Ptr(kMaxDisplays:Int, display:Byte Ptr, numDisplays:Int Var)"MacOS"
        Function MACOS_GetWidth:Int(mode:Byte Ptr)"C"
        Function MACOS_GetHeight:Int(mode:Byte Ptr)"C"
        Function MACOS_GetBPP:Int(mode:Byte Ptr)"C"
        Function MACOS_GetHertz:Int(mode:Byte Ptr)"C"
    End Extern 
    Public
?Linux
    Import brl.graphics
?

Function GetDesktopMode:Int (width:Int Var, height:Int Var, depth:Int Var, hertz:Int Var)
    ?win32
        Local hwnd:Int = GetDesktopWindow()
        Local hdc:Int = GetDC(hwnd)
        If hdc = Null Then Return -1
        width  = GetDeviceCaps(hdc, HORZRES)
        height = GetDeviceCaps(hdc, VERTRES)
        depth  = GetDeviceCaps(hdc, BITSPIXEL)
        hertz  = GetDeviceCaps(hdc, VREFRESH)
        ReleaseDC(hwnd,hdc)
    ?MacOS
        Local display:Byte Ptr[] = New Byte Ptr[1]
        Local iMode:Byte Ptr = Null
        Local iCount:Int
        CGGetActiveDisplayList 1, display, iCount
        iMode  = CGDisplayCurrentMode(display[0])
        width  = MACOS_GetWidth(iMode)
        height = MACOS_GetHeight(iMode)
        depth  = MACOS_GetBPP(iMode)
        hertz  = MACOS_GetHertz(iMode)
    ?Linux
        CountGraphicsModes()
        GetGraphicsMode (0,width,height,depth,hertz)
    ?
End Function

' Получать так : '
Local desktopWidth:Int, desktopHeight:Int, desktopDepth:Int, desktopHertz:Int
GetDesktopMode(desktopWidth, desktopHeight, desktopDepth, desktopHertz)
Graphics(desktopWidth, desktopHeight, desktopDepth, desktopHertz)